Vla-put-visible

AutoLISP Home - AutoLISP 目次 - DCL - AutoLisp関数互換表 - CAD&CGブログ - オンラインショップ- GizmoTools ヘルプセンター

構文

(vla-put-visible vla-object bool)

機能

ツールバーの表示状態を指定する。

引数

• vla-object … VLAオブジェクト(すべての図形オブジェクト、Application、AttributeReference、Group、Toolbar)
• bool … :vlax-true or :vlax-false

戻り値

nil

• 注意
  • オブジェクトを非表示に指定すると、アプリケーションの可視設定にかかわらず見えなくなる。オブジェクトが見えなくなる原因は画層がオフまたはフリーズになっているなど他にもあり、そのオブジェクトは表示されない。
  • アプリケーションを見えないように指定すると、コンポーネントを見ないでバックグラウンドのタスクを実行できる。

サンプル

(vl-load-com)
(defun c:Example_Float()
    ;;「TestToolbar」という名の新しいツールバーを作成し、3つのボタンを挿入。
    ;; ツールバーをフローティングツールバー、ドッキングで表示するサンプル。
    (setq currMenuGroup (vla-Item (vla-get-MenuGroups (vlax-get-acad-object)) 0))

    ;; 新しいツールバーを生成
    (setq newToolBar (vla-Add (vla-get-Toolbars currMenuGroup) "TestToolbar"))

    ;; 生成したツールバーに３つのボタンを追加
    ;; ボタンの割り当てマクロは同じ
    (setq openMacro (strcat (Chr 3) (Chr 3) (Chr 95) "open" (Chr 32)))

    (setq newButton1 (vla-AddToolbarButton newToolBar "" "NewButton1" "Open a file." openMacro))
    (setq newButton2 (vla-AddToolbarButton newToolBar "" "NewButton2" "Open a file." openMacro))
    (setq newButton3 (vla-AddToolbarButton newToolBar "" "NewButton3" "Open a file." openMacro))    

    ;; ツールバー表示
    (vla-put-Visible newToolBar :vlax-true)

    ;; 画面の左側にあるツールバーを固定。
    (vla-Dock newToolBar acToolbarDockLeft)

    ;; それがドッキングされているかどうかを確認するために、ツールバーを照会します。
    (if (= (vla-get-DockStatus newToolBar) acToolbarFloating)
        (alert "ツールバーはフローティング")
        (alert "ツールバーはドッキング")
    )

    ;; ツールバーをフロート
    (vla-Float newToolBar 200 200 1)

    (if (= (vla-get-DockStatus newToolBar) acToolbarFloating)
        (alert "The toolbar is floating.")
        (alert "The toolbar is docked.")
    )
)

---

関連事項

• vlax-get-acad-object
• vla-get-documents
• vla-get-dockstatus
• vla-get-menugroups
• vla-get-toolbars
• vla-addtoolbarbutton
• vla-put-visible
• vla-float
• vla-dock
• vla-item