Vla-get-dockstatus

提供:GizmoLabs - だいたい CAD LISP なサイト
構文
(vla-get-dockstatus vla-object)


機能
ツールバーのドッキング状態を取得する。


引数
  • vla-object … ToolBar の VLAオブジェクトオブジェクト


戻り値
acToolbarDockStatus 列挙型のいずれか
  • acToolbarDockTop … 上部にドッキング
  • acToolbarDockBottom … 下部にドッキング
  • acToolbarDockLeft … 左にドッキング
  • acToolbarDockRight … 右にドッキング
  • acToolbarFloating … フローティング


サンプル
(vl-load-com)
(defun c:Example_Float()
    ;;「TestToolbar」という名の新しいツールバーを作成し、3つのボタンを挿入。
    ;; ツールバーをフローティングツールバー、ドッキングで表示。
    (setq currMenuGroup (vla-Item (vla-get-MenuGroups (vlax-get-acad-object)) 0))

    ;; 新しいツールバーを生成
    (setq newToolBar (vla-Add (vla-get-Toolbars currMenuGroup) "TestToolbar"))

    ;; 生成したツールバーに3つのボタンを追加
    ;; ボタンの割り当てマクロは同じ
    (setq openMacro (strcat (Chr 3) (Chr 3) (Chr 95) "open" (Chr 32)))

    (setq newButton1 (vla-AddToolbarButton newToolBar "" "NewButton1" "Open a file." openMacro))
    (setq newButton2 (vla-AddToolbarButton newToolBar "" "NewButton2" "Open a file." openMacro))
    (setq newButton3 (vla-AddToolbarButton newToolBar "" "NewButton3" "Open a file." openMacro))    

    ;; ツールバー表示
    (vla-put-Visible newToolBar :vlax-true)

    ;; 画面の左側にあるツールバーを固定。
    (vla-Dock newToolBar acToolbarDockLeft)

    ;; それがドッキングされているかどうかを確認するために、ツールバーを照会します。
    (if (= (vla-get-DockStatus newToolBar) acToolbarFloating)
        (alert "ツールバーはフローティング")
        (alert "ツールバーはドッキング")
    )

    ;; ツールバーをフロート
    (vla-Float newToolBar 200 200 1)

    (if (= (vla-get-DockStatus newToolBar) acToolbarFloating)
        (alert "The toolbar is floating.")
        (alert "The toolbar is docked.")
    )
)

関連事項