Vla-put-verticaltextposition

提供: GizmoLabs - だいたい CAD LISP なサイト
移動先: 案内検索
構文
(vla-put-verticaltextposition vla-object 'position)


機能
寸法線に対する寸法値の垂直方向の位置を指定する。


引数
  • vla-object … VLAオブジェクト(Dim3PointAngular、DimAligned、DimAngular、DimArcLength、DimDiametric、Dimension、DimOrdinate、DimRadial、DimRadialLarge、DimRotated、Leader)
  • position … acDimVerticalJustification 列挙型
  • acVertCentered: 寸法値を寸法補助線間の中央に記入する。
  • acAbove: 寸法線が水平ではなく、寸法補助線の内側の寸法値が強制水平(DIMTIH[補助線内水平] = 1)でない限り、寸法線の上に寸法値を記入する。寸法線から寸法値の基準線(最下線)までの距離が、DIMGAP[寸法ギャップ]の現在値。
  • acUnder: 寸法線が水平ではなく、寸法補助線の内側の寸法値が強制水平(DIMTIH[補助線内水平] = 1)でない限り、寸法線の下に寸法値を記入する。寸法線から寸法値の基準線(最下線)までの距離が、DIMGAP[寸法ギャップ]の現在値。
  • acOutside: 寸法値を、定義点から最も遠くにある寸法線の横に記入する。
  • acJIS: 寸法値を JIS(日本工業規格)に準拠するように記入する。


戻り値
nil


  • MEMO : このプロパティの初期値は acVertCentered 。

注: このプロパティは、指定された寸法、引出線、または幾何公差オブジェクトでシステム変数 DIMTAD[寸法線上記入]の値を変更します。


サンプル
(vl-load-com)
(defun c:Example_VerticalTextPosition()
    ;; 寸法を作成して寸法値の垂直方向の位置を変更するサンプル
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))
    
    ;; 寸法の定義
    (setq point1 (vlax-3d-point 5 5 0)
          point2 (vlax-3d-point 9 5 0)
          location (vlax-3d-point 5 7 0))  
    
    ;; 寸法を作成
    (setq modelSpace (vla-get-ModelSpace doc))  
    (setq dimObj (vla-AddDimAligned modelSpace point1 point2 location))
    (vla-ZoomAll acadObj)

    ;; 既定値を読み込み
    (setq CurrentValue (cond
                           ((= (vla-get-VerticalTextPosition dimObj) acVertCentered) "中心")
                           ((= (vla-get-VerticalTextPosition dimObj) acAbove) "上")
                           ((= (vla-get-VerticalTextPosition dimObj) acOutside) "外")
                           ((= (vla-get-VerticalTextPosition dimObj) acJIS) "JIS準拠")
                           ((= (vla-get-VerticalTextPosition dimObj) acUnder) "下")
                       ))
    
    (alert (strcat "現在の寸法値の垂直方向は : " CurrentValue))

    ;; 変更
    (vla-put-VerticalTextPosition dimObj acAbove)
    (vla-Regen doc acAllViewports)
    (alert "寸法値の垂直方向を上に変更")
   
    ;; 変更
    (vla-put-VerticalTextPosition dimObj acVertCentered)
    (vla-Regen doc acAllViewports)
    (alert "寸法値の垂直方向を中心に変更")

    ;; 変更
    (vla-put-VerticalTextPosition dimObj acJIS)
    (vla-Regen doc acAllViewports)
    (alert "寸法値の垂直方向をJIS準拠に変更")
)

関連事項