Vla-put-gradientangle

提供: GizmoLabs - だいたい CAD LISP なサイト
移動先: 案内検索
構文
(vla-put-gradientangle vla-object angle)


機能
グラデーションの角度を指定する。


引数
  • vla-object … Hatch の VLAオブジェクト
  • angle… グラデーション パターンの角度。 ラジアン(ACAD_ANGLE)


戻り値
nil


サンプル

(vl-load-com)
(defun c:Example_gradientangle()
    ;; グラデーションの角度を変更するサンプル
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))    
    
    ;; ハッチングの定義
    (setq patternName "CYLINDER")
    (setq patternType acPreDefinedGradient)
    (setq bAssociativity :vlax-true)
    
    ;; ハッチングのオブジェクトを作成
    (setq modelSpace (vla-get-ModelSpace doc))  
    (setq hatchObj (vla-AddHatch modelSpace patternType patternName bAssociativity acGradientObject))

    (setq col1 (vlax-create-object "AutoCAD.AcCmColor.20")) ; バージョンに合わせること
    (setq col2 (vlax-create-object "AutoCAD.AcCmColor.20")) ; 同上

    (vla-SetRGB col1 255 0 0)
    (vla-SetRGB col2 0 255 0)

    (vla-put-GradientColor1 hatchObj col1)
    (vla-put-GradientColor2 hatchObj col2)
    
    ;; 境界の円を作成
    (setq center (vlax-3d-point 3 3 0)
          radius 1)
    (setq circle (vla-AddCircle modelSpace center radius))

    (setq outerLoop (vlax-make-safearray vlax-vbObject '(0 . 0)))
    (vlax-safearray-put-element outerLoop 0 circle)
    
    ;; ハッチング境界を作成
    (vla-AppendOuterLoop hatchObj outerLoop)
    (vla-Evaluate hatchObj)
    (vla-Regen doc :vlax-true)

    (alert (strcat "現在の GradientAngle は " (rtos (vla-get-GradientAngle hatchObj) 2)))
    (vla-put-GradientAngle hatchObj (/ pi 4))
    (alert (strcat "新しい GradientAngle は " (rtos (vla-get-GradientAngle hatchObj) 2)))


    (vlax-release-object col1)
    (vlax-release-object col2)
)


関連事項