Vla-put-dimline2suppress

提供: GizmoLabs - だいたい CAD LISP なサイト
移動先: 案内検索
構文
(vla-put-dimline2suppress vla-object bool )


機能
2 本目の寸法線の省略を指定する。


引数
  • vla-object … VLAオブジェクト(Dim3PointAngular、DimAligned、DimAngular、DimArcLength、DimDiametric、DimRotated)
  • bool … ブール型
  •  :vlax-True: 2 本目の寸法線を省略する。
  •  :vlax-False: 2 本目の寸法線を省略しない。


戻り値
nil


  • MEMO:このプロパティの初期値は False 。
  • このプロパティが True に設定されている場合、2 本目の寸法補助線と寸法値の間の寸法線と矢印の表示は省略される。
  • 注 : このプロパティは、指定された寸法でシステム変数 DIMSD2[寸法線省略 /2]の値よりも優先される。


サンプル
(vl-load-com)
(defun c:Example_DimensionLine1-2Suppress()
    ;; Dim3PointAngular オブジェクトを作成し、DimensionLine1Suppress と
    ;; DimensionLine2Suppress プロパティを使用して寸法線を抑制するサンプル
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))
    
    ;; Dim3PointAngular の定義
    (setq AngleVertex (vlax-3d-point 0 0 0)
          FirstPoint (vlax-3d-point 2 2 0)
          SecondPoint (vlax-3d-point 1 4 0)
          TextPoint (vlax-3d-point 6 6 0))

    ;; Dim3PointAngular を作成
    (setq modelSpace (vla-get-ModelSpace doc))  
    (setq DimPointAngularObj (vla-AddDim3PointAngular modelSpace AngleVertex FirstPoint SecondPoint TextPoint))
    (vla-ZoomAll acadObj)

    ;; 現在の設定を取得
    (setq Line1Suppressed (if (= (vla-get-DimLine1Suppress DimPointAngularObj) :vlax-true) "抑制される。" "抑制されません。"))
    (setq Line2Suppressed (if (= (vla-get-DimLine2Suppress DimPointAngularObj) :vlax-true) "抑制される。" "抑制されません。"))
    
    (alert (strcat "1本目の寸法線は " Line1Suppressed
                   "\n2本目の寸法線は " Line2Suppressed))

    ;; 1本目の寸法線を変更
    (vla-put-DimLine1Suppress DimPointAngularObj :vlax-true)
    (vla-Regen doc acAllViewports)
    (alert "1本目の寸法線を表示を抑制。")
    
    ;; 2本目の寸法線を変更
    (vla-put-DimLine2Suppress DimPointAngularObj :vlax-true)
    (vla-Regen doc acAllViewports)
    (alert "2本目の寸法線を表示を抑制。")
   
    ;; 変更
    (vla-put-DimLine1Suppress DimPointAngularObj :vlax-false)
    (vla-put-DimLine2Suppress DimPointAngularObj :vlax-false)
    (vla-Regen doc acAllViewports)
    (alert "寸法線を1,2本目共を表示に変更")
)

関連事項