Vla-put-arrowhead1type

提供:GizmoLabs - だいたい CAD LISP なサイト
構文
(vla-put-arrowhead1type vla-object type)


機能
寸法線の第 1 端点のカスタム矢印のタイプを取得する。


引数
  • vla-object … VLAオブジェクト(Dim3PointAngular、DimAligned、DimAngular、DimArcLength、DimDiametric、DimRotated)
  • type … acDimArrowheadType 列挙型
  • acArrowDefault
  • acArrowDot
  • acArrowDotSmall
  • acArrowDotBlank
  • acArrowOrigin
  • acArrowOrigin2
  • acArrowOpen
  • acArrowOpen90
  • acArrowOpen30
  • acArrowClosed
  • acArrowSmall
  • acArrowNone
  • acArrowOblique
  • acArrowBoxFilled
  • acArrowBoxBlank
  • acArrowClosedBlank
  • acArrowDatumFilled
  • acArrowDatumBlank
  • acArrowIntegral
  • acArrowArchTick
  • acArrowUserDefined 読み込み専用
戻り値
nil


  • MEMO : このプロパティの初期値は acArrowDefault。このプロパティが acArrowUserDefined に設定されている場合、Arrowhead1Block プロパティを使用してカスタム矢印として使用するブロックを指定する。
  • 注 : このプロパティは、指定された寸法でシステム変数 DIMBLK1[矢印名 1]の値を変更する。


サンプル
(vl-load-com)
(defun c:Example_ArrowHead1Type()
    ;; 三点角度寸法を作成して矢印1,2を変更するサンプル
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))

    ;; 三点角度寸法の定義
    (setq AngleVertex (vlax-3d-point 0 0 0)
          FirstPoint (vlax-3d-point 2 2 0)
          SecondPoint (vlax-3d-point 1 4 0)
          TextPoint (vlax-3d-point 6 6 0))

    ;; 三点角度寸法を作成
    (setq modelSpace (vla-get-ModelSpace doc))  
    (setq DimPointAngularObj (vla-AddDim3PointAngular modelSpace AngleVertex FirstPoint SecondPoint TextPoint))
    (vla-ZoomAll acadObj)

    ;; 矢印タイプを読み込んで表示
    (alert (strcat "この図形の矢印1のタイプは: " (itoa (vla-get-Arrowhead1Type DimPointAngularObj))
                   "\n矢印2のタイプは:" (itoa (vla-get-Arrowhead2Type DimPointAngularObj))))

    ;; 矢印を空白四角に変更
    (vla-put-Arrowhead1Type DimPointAngularObj acArrowBoxBlank)
    (vla-put-Arrowhead2Type DimPointAngularObj acArrowBoxBlank)
    (vla-Regen doc acAllViewports)

    ;; 矢印タイプを読み込んで表示
    (alert (strcat "この図形の矢印1のタイプを次にセット: " (itoa (vla-get-Arrowhead1Type DimPointAngularObj))
                   "\n矢印2の矢印タイプを次にセット: " (itoa (vla-get-Arrowhead2Type DimPointAngularObj))))
)


関連事項