Vla-get-helpstring

AutoLISP Home - AutoLISP 目次 - DCL - AutoLisp関数互換表 - CAD&CGブログ - オンラインショップ- GizmoTools ヘルプセンター

構文: (vla-get-helpstring vla-object)

機能: ツールバー、ツールバー項目、メニュー項目のヘルプ文字列を取得する。

引数

vla-object … VLA オブジェクト（: PopupMenuItem、Toolbar、ToolbarItem）

戻り値: ツールバー、ツールバー項目、メニュー項目のヘルプ文字列

注意

ヘルプ文字列は、ユーザがメニュー項目をハイライト表示したときに CAD のステータス行（またはツールチップ）に表示される文字列。

サンプル

(vl-load-com)
(defun c:Example_HelpString()
    ;; "TestToolbar" っていうツールバーを生成して呼び出し、
    ;; ボタンの追加とヘルプ文字を変更するサンプル。
    ;; 追加されたものは、手動で削除

    (setq acadObj (vlax-get-acad-object))
    (setq currMenuGroup (vla-Item (vla-get-MenuGroups acadObj) 0))
    
    ;; 新しいツールバーを作成
    (setq newToolBar (vla-Add (vla-get-Toolbars currMenuGroup) "TestToolbar"))
    
    ;; ツールバーにボタンを追加
    ;; 設定するマクロは "ESC ESC _open "
    (setq openMacro (strcat (Chr 3) (Chr 3) (Chr 95) "open" (Chr 32)))
    (setq newButton1 (vla-AddToolbarButton newToolBar "" "新しい釦1" "ファイルを開く" openMacro))
    
    ;; ツールバーを表示
    (vla-put-Visible newToolBar :vlax-true)
    
    ;; ヘルプ文字列を読み込み
    (alert (strcat "現在釦に設定されているヘルプ文字は : " (vla-get-HelpString newButton1)))
    
    ;; ヘルプ文字を変更
    (vla-put-HelpString newButton1 "この釦はファイルを開くらしい。")
    
    ;; 新しいヘルプ文字列を読み込み
    (alert (strcat "現在釦に設定されているヘルプ文字は : " (vla-get-HelpString newButton1)))
)