Vla-get-patterntype

AutoLISP Home - AutoLISP 目次 - DCL - AutoLisp関数互換表 - CAD&CGブログ - オンラインショップ- GizmoTools ヘルプセンター

構文: (vla-get-patterntype vla-object )

機能: ハッチングに使用するパターンのタイプを取得する。

引数

vla-object … Hatch のVLAオブジェクト

戻り値

acPatternType 列挙型

acHatchPatternTypePreDefined: acad.pat ファイルに定義されている中からパターン名を選択する。
acHatchPatternTypeUserDefined: 現在の線種を使用して、線分のパターンを定義する。
acHatchPatternTypeCustomDefined: acad.pat ファイル以外の PAT ファイルからパターン名を選択する。

MEMO：ハッチングパターンのタイプは、AddHatch メソッド(ハッチングの作成の場合)または SetPattern メソッドによってのみ設定できる。

サンプル

(vl-load-com)
(defun c:Example_PatternType()
    ;; モデル空間で自動調整ハッチングを作成する。
    ;; ハッチング パターンの種類が返される。
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))
    
    ;; ハッチの定義
    (setq patternName "ANSI31"
          patternType acHatchPatternTypePreDefined
          bAssociativity :vlax-true)
    
    ;; 自動調整ハッチング オブジェクトを作成する。
    (setq modelSpace (vla-get-ModelSpace doc))  
    (setq hatchObj (vla-AddHatch modelSpace patternType patternName bAssociativity acHatchObject))
    
    ;; ハッチの外側のループを作成する。
    ;; 円弧とラインは、閉じたループを作成する使用される。
    (setq center (vlax-3d-point 5 3 0)
          radius 3
          startAngle 0
          endAngle 3.141592)

    (setq arc (vla-AddArc modelSpace center radius startAngle endAngle))
    (setq line (vla-AddLine modelSpace (vla-get-StartPoint arc) (vla-get-EndPoint arc)))
  
    (setq outerLoop (vlax-make-safearray vlax-vbObject '(0 . 1)))
    (vlax-safearray-put-element outerLoop 0 arc)
    (vlax-safearray-put-element outerLoop 1 line)
        
    ;; ハッチング オブジェクトに外側のループを追加。
    (vla-AppendOuterLoop hatchObj outerLoop)
    
    ;; 内側のループとして最初の円を追加。
    (setq center (vlax-3d-point 5 4.5 0)
          radius 1)
    (setq circle1 (vla-AddCircle modelSpace center radius))

    (setq innerLoop1 (vlax-make-safearray vlax-vbObject '(0 . 0)))
    (vlax-safearray-put-element innerLoop1 0 circle1)

    (vla-AppendInnerLoop hatchObj innerLoop1)
    
    ;; 内側のループとして 2 番目の円を追加。
    (setq radius 0.5)
    (setq innerLoop2 (vlax-make-safearray vlax-vbObject '(0 . 0)))
    (setq circle2 (vla-AddCircle modelSpace center radius))
    (vlax-safearray-put-element innerLoop2 0 circle2)

    (vla-AppendInnerLoop hatchObj innerLoop2)
    
    ;; ハッチを評価して表示
    (vla-Evaluate hatchObj)
    (vla-Regen doc :vlax-true)
    
    ;; ハッチタイプを取得
    (setq patternType (vla-get-PatternType hatchObj))
    (alert (strcat "ハッチタイプは " 
                   (cond
                     ((= patternType acHatchPatternTypeUserDefined) "acHatchPatternTypeUserDefined")
                     ((= patternType acHatchPatternTypePreDefined) "acHatchPatternTypePreDefined")
                     ((= patternType acHatchPatternTypeCustomDefined) "acHatchPatternTypeCustomDefined")
                   )))
)