Vla-get-patternname

AutoLISP Home - AutoLISP 目次 - DCL - AutoLisp関数互換表 - CAD&CGブログ - オンラインショップ- GizmoTools ヘルプセンター

構文: (vla-get-patternname vla-object )

機能: ハッチングパターンの名前を指定する。

引数

vla-object … Hatch のVLAオブジェクト

戻り値: ハッチングパターンの名前。

MEMO：既定のハッチングパターン名は、スペースを含まない最大 34 文字の名前。既定値が設定されていないと null 値("")が返される。既定を設定しない場合は、ピリオド(.)を 1 つ入力する。
PatternType プロパティが acHatchPatternTypePreDefined に設定されている場合、PatternName プロパティは acad.pat 内のハッチングパターンの名前を参照する。
PatternType プロパティが acHatchPatternTypeCustomDefined に設定されている場合、PatternName プロパティはカスタムの .pat ファイル内のハッチングパターンの名前を参照する。
PatternType プロパティが acHatchPatternTypeUserDefined に設定されている場合、PatternName プロパティは使用されない。
注 : このプロパティの値は、システム変数 HPNAME に格納される。

サンプル

(vl-load-com)
(defun c:Example_PatternName()
    ;; 、モデル空間で自動調整ハッチングを作成してハッチング パターンの名前を取得するサンプル
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))
    
    ;; ハッチングの定義
    (setq patternName "ANSI31"
          patternType 0
          bAssociativity :vlax-true)
    
    ;; ハッチを作成
    (setq modelSpace (vla-get-ModelSpace doc))  
    (setq hatchObj (vla-AddHatch modelSpace patternType patternName bAssociativity acHatchObject))
    
    ;; ハッチの境界を作成
    ;; 円弧とラインは、閉じたループを作成する使用されます。
    (setq center (vlax-3d-point 5 3 0) 
          radius 3
          startAngle 0
          endAngle 3.141592)
    
    (setq arc (vla-AddArc modelSpace center radius startAngle endAngle))
    (setq line (vla-AddLine modelSpace (vla-get-StartPoint arc) (vla-get-EndPoint arc)))
  
    (setq outerLoop (vlax-make-safearray vlax-vbObject '(0 . 1)))
    (vlax-safearray-put-element outerLoop 0 arc)
    (vlax-safearray-put-element outerLoop 1 line)
        
    ;; ハッチング オブジェクトに外側のループを追加。
    (vla-AppendOuterLoop hatchObj outerLoop)
    
    ;; 1 つの内側のループとして最初の円を追加。
    (setq center (vlax-3d-point 5 4.5 0)  
          radius 1)
    (setq circle1 (vla-AddCircle modelSpace center radius))

    (setq innerLoop1 (vlax-make-safearray vlax-vbObject '(0 . 0)))
    (vlax-safearray-put-element innerLoop1 0 circle1)

    (vla-AppendInnerLoop hatchObj innerLoop1)
    
    ;; 内側のループとして 2 番目の円を追加。
    (setq radius 0.5)
    (setq innerLoop2 (vlax-make-safearray vlax-vbObject '(0 . 0)))
    (setq circle2 (vla-AddCircle modelSpace center radius))
    (vlax-safearray-put-element innerLoop2 0 circle2)

    (vla-AppendInnerLoop hatchObj innerLoop2)
    
    ;; Evaluate and display the hatch
    (vla-Evaluate hatchObj)
    (vla-Regen doc :vlax-true)
    
    ;; ハッチング パターンの名前を取得
    (setq patternName (vla-get-PatternName hatchObj))
    (alert (strcat "ハッチング パターンの名前は " patternName))
)