Vla-setpattern

AutoLISP Home - AutoLISP 目次 - DCL - AutoLisp関数互換表 - CAD&CGブログ - オンラインショップ- GizmoTools ヘルプセンター

構文: (vla-setpattern vla-object PatternType PatternName )

機能: ハッチングのパターン名とパターンタイプを設定する。

引数

vla-object … Hatch の VLAオブジェクト
PatternType … AcPatternType 列挙型

acHatchPatternTypePreDefined : acad.pat ファイルに定義されている中からパターン名を選択する。
acHatchPatternTypeUserDefined : 現在の線種を使用して、線分のパターンを定義する。
acHatchPatternTypeCustomDefined : acad.pat ファイル以外の PAT ファイルからパターン名を選択する。

PatternName … パターン名。スペースを含まない 34 文字以内の既定のハッチングパターン名を設定する。既定値が設定されていないと null 値("")が返される。既定を設定しない場合は、ピリオド(.)を 1 つ入力する。

戻り値: nil

MEMO: ハッチングパターンのタイプは次の設定のいずれかで定義される。
PreDefined: 標準のパターンファイル（acad.pat, acadiso.pat, etc）に定義されている中からパターン名を選択する。
UserDefined: 現在の線種を使用して、線分のパターンを定義する。
CustomDefined: 標準のパターンファイル以外の PAT ファイルからパターン名を選択する。
注 : SetPattern メソッドは、アクティブなドキュメントに対してのみ使用すること。

サンプル

(vl-load-com)
(defun c:Example_SetPattern()
    ;; 異尺度ハッチを作成してパターンを変更するサンプル
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))
  
    ;; ハッチの定義
    (setq patternName "ANSI31"
          patternType 0
          bAssociativity :vlax-true)
    
    ;; ハッチを作成
    (setq modelSpace (vla-get-ModelSpace doc))  
    (setq hatchObj (vla-AddHatch modelSpace patternType patternName bAssociativity acHatchObject))
    
    ;; ハッチ境界を作成
    ;; An arc and a line are used to create a closed loop.
    (setq center (vlax-3d-point 5 3 0) 
          radius 3
          startAngle 0
          endAngle 3.141592)
  
    (setq arc (vla-AddArc modelSpace center radius startAngle endAngle))
    (setq line (vla-AddLine modelSpace (vla-get-StartPoint arc) (vla-get-EndPoint arc)))
  
    (setq outerLoop (vlax-make-safearray vlax-vbObject '(0 . 1)))
    (vlax-safearray-put-element outerLoop 0 arc)
    (vlax-safearray-put-element outerLoop 1 line)
        
    ;; 境界を追加
    (vla-AppendOuterLoop hatchObj outerLoop)
    
    ;; 最初の外側の円を境界に
    (setq center (vlax-3d-point 5 4.5 0)  
          radius 1)
    (setq circle1 (vla-AddCircle modelSpace center radius))

    (setq innerLoop1 (vlax-make-safearray vlax-vbObject '(0 . 0)))
    (vlax-safearray-put-element innerLoop1 0 circle1)

    (vla-AppendInnerLoop hatchObj innerLoop1)
    
    ;; ２つめの円を境界に
    (setq radius 0.5)
    (setq innerLoop2 (vlax-make-safearray vlax-vbObject '(0 . 0)))
    (setq circle2 (vla-AddCircle modelSpace center radius))
    (vlax-safearray-put-element innerLoop2 0 circle2)

    (vla-AppendInnerLoop hatchObj innerLoop2)
    
    ;; ハッチを評価
    (vla-Evaluate hatchObj)
    (vla-ZoomAll acadObj)
    
    ;; ハッチのパターン名を表示
    (setq patternName (vla-get-patternName hatchObj))
    (alert (strcat "ハッチはターン名は " patternName))
                   
    ;; ハッチパターンを変更
    (vla-SetPattern hatchObj acHatchPatternTypePreDefined "BRICK")
    (vla-Evaluate hatchObj)
    (vla-Regen doc :vlax-true)
    (alert (strcat "新しハッチパターンは " (vla-get-patternName hatchObj)))
)