Vla-gettextheight

AutoLISP Home - AutoLISP 目次 - DCL - AutoLisp関数互換表 - CAD&CGブログ - オンラインショップ- GizmoTools ヘルプセンター

構文: (vla-gettextheight vla-object rowType )

機能: 指定した行タイプの文字高さを返す。

引数

vla-object … VLAオブジェクト(Table、TableStyle)
rowType … 行タイプ。AcRowType 列挙型

acDataRow
acHeaderRow
acTitleRow
acUnknownRow

戻り値: 指定した行タイプの文字高さ。

サンプル

(vl-load-com)
(defun c:Example_GetTextHeight()
    ;; TableStyle オブジェクトを作成し、スタイルの名前とその他の属性の値を
    ;; 設定するサンプル。
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))
  
    (setq dictionaries (vla-get-Dictionaries doc))
    (setq dictObj (vla-Item dictionaries "acad_tablestyle"))
    
    ;; 辞書でカスタム TableStyle オブジェクトを作成する。
    (setq keyName "NewStyle"
          className "AcDbTableStyle")
  
    (setq customObj (vla-AddObject dictObj keyName className))
      
    (vla-put-Name customObj "NewStyle")
    (vla-put-Description customObj "新しい俺のスタイル")
  
    (vla-put-FlowDirection customObj acTableBottomToTop)
    (vla-put-HorzCellMargin customObj 0.22)
    (vla-put-BitFlags customObj 1)
    (vla-SetTextHeight customObj (+ acDataRow acTitleRow) 1.3)
    (vla-SetTextStyle customObj (+ acDataRow acTitleRow) "Standard")

    (setq col (vlax-create-object "AutoCAD.AcCmColor.20"))
    (vla-SetRGB col 12 23 45)

    (vla-SetBackgroundColor customObj (+ acDataRow acTitleRow) col)
    (vla-SetGridVisibility customObj (+ acHorzInside acHorzTop) (+ acDataRow acTitleRow) :vlax-true)
    (vla-SetAlignment customObj (+ acDataRow acTitleRow) acBottomRight)
    (vla-SetRGB col 244 0 0)
    (vla-SetGridColor customObj (+ acHorzTop acHorzInside) acDataRow col)

    (alert (strcat "テーブルスタイル名 = " (vla-get-Name customObj)
                   "\nスタイルの説明 = " (vla-get-Description customObj)
                   "\n流れ方向 = " (itoa (vla-get-FlowDirection customObj))
                   "\n水平セル余白 = " (rtos (vla-get-HorzCellMargin customObj) 2)
                   "\nビット フラグ = " (itoa (vla-get-BitFlags customObj))
                   "\nタイトル行の文字の高さ = " (rtos (vla-GetTextHeight customObj acTitleRow) 2)
                   "\nタイトル行テキスト スタイル = " (vla-GetTextStyle customObj acTitleRow)
                   "\nHorizontalBottom TitleRow のグリッドの可視性 = " (if (= (vla-GetGridVisibility customObj acHorzBottom acTitleRow) :vlax-true) "True" "False")
                   "\nタイトル行の配置 = " (itoa (vla-GetAlignment customObj acTitleRow))
                   "\nヘッダーの抑制 = " (if (= (vla-get-HeaderSuppressed customObj) :vlax-true) "True" "False")
          )
    )
    (vlax-release-object col)  
)