Vla-put-tolerancesuppresszerofeet

AutoLISP Home - AutoLISP 目次 - DCL - AutoLisp関数互換表 - CAD&CGブログ - オンラインショップ- GizmoTools ヘルプセンター

構文: (vla-put-tolerancesuppresszerofeet vla-object bool)

機能: 寸法許容差値の 0 フィート計測値の省略を指定する。

引数

vla-object … VLAオブジェクト（DimAligned、DimArcLength、DimDiametric、DimOrdinate、DimRadial、DimRadialLarge、DimRotated）
bool … ブール型

:vlax-True: 0 フィートの寸法表示は省略。
:vlax-False: 0 フィートの寸法表示は省略しない。

戻り値: nil

このプロパティの初期値は False。
注: このプロパティは、指定された寸法でシステム変数 DIMTZIN[寸法許容差 0 省略]の値を変更する。

サンプル

(vl-load-com)
(defun c:Example_ToleranceSuppressZeroFeet()
    ;; モデル空間に平行寸法を作成し、寸法公差の表示でゼロフィートの表示を切り替えることが ToleranceSuppressZeroFeet を使用しています
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))
    
    ;;寸法の設定
    (setq point1 (vlax-3d-point 5 5 0)
          point2 (vlax-3d-point 6.01 5 0)
          location (vlax-3d-point 5 8 0))
    
    ;; モデルに平行寸法を作成
    (setq modelSpace (vla-get-ModelSpace doc))
    (setq dimObj (vla-AddDimAligned modelSpace point1 point2 location))
    (vla-put-UnitsFormat dimObj acDimLArchitectural)
    
    ;; 寸法許容差を設定
    (vla-put-ToleranceDisplay dimObj acTolLimits)
    (vla-put-ToleranceLowerLimit dimObj -0.0001)
    (vla-put-ToleranceUpperLimit dimObj 0.0001)

    (vla-ZoomAll acadObj)

    ;; 寸法公差値の ゼロフィート表示を切り替え
    (vla-put-ToleranceSuppressZeroFeet dimObj (if (= (vla-get-ToleranceSuppressZeroFeet dimObj) :vlax-true) :vlax-false :vlax-true))
    (vla-Regen doc acAllViewports)
    (alert "寸法公差値のゼロフィート表示をトグル")

    ;; 寸法公差値のゼロフィートの表示を切り替え
    (vla-put-ToleranceSuppressZeroFeet dimObj (if (= (vla-get-ToleranceSuppressZeroFeet dimObj) :vlax-true) :vlax-false :vlax-true))
    (vla-Regen doc acAllViewports)
    (alert "寸法公差値のゼロフィート表示をもどします。")
)