Vla-startbatchmode

AutoLISP Home - AutoLISP 目次 - DCL - AutoLisp関数互換表 - CAD&CGブログ - オンラインショップ- GizmoTools ヘルプセンター

構文: (vla-startbatchmode vla-object entryCount)

機能: バッチモードで印刷を開始する。(旧式)

引数

vla-object … Plot の VLAオブジェクト
entryCount … バッチで印刷するエントリの数。

戻り値: なし

注意 : このメソッドは旧式で、AutoCAD 2005 の時点で将来のバージョンでは除去される予定となっている。

サンプル

(defun C:PLOTSETS (/ lst llst numCopies name acadobj doc layouts plotobj)
  (vl-load-com)
  (setq acadobj (vlax-get-acad-object)
        doc     (vla-get-activeDocument acadobj)
        layouts (vla-get-layouts doc)
        plotobj (vla-get-plot doc))
  (vlax-for layout layouts
    (if (/= (setq name (vla-get-name layout)) "Model")
      (setq lst (cons (list (vla-get-tabOrder layout)
                            name
                            (vla-get-configName layout)
                      ) lst))))
  (setq lst  (vl-sort lst (function (lambda (a b) (< (car a) (car b)))))
        llst (mapcar 'cadr lst))
  (cond 
    ((> (setq numCopies (getint "\n出力枚数 : ")) 0)
      (progn
        (vla-setLayoutsToPlot
          plotobj
          (vlax-make-variant
             (vlax-safearray-fill
               (vlax-make-safearray vlax-vbString (cons 0 (1- (length llst))))
               llst)))
        (vla-startBatchMode plotobj (length llst))
        (vla-put-numberOfCopies plotobj numCopies)
        (vla-plotToDevice plotobj)
        (vla-put-numberOfCopies plotobj 1)))
    (T (princ "\n無理っぽ"))
  )
  (mapcar 'vlax-release-object (list plotobj layouts doc acadobj))
  (princ)
)