Vla-addextrudedsolid

AutoLISP Home - AutoLISP 目次 - DCL - AutoLisp関数互換表 - CAD&CGブログ - オンラインショップ- GizmoTools ヘルプセンター

構文: (vla-addextrudedsolid vla-object Profile Height TaperAngle 　)

機能: 押し出しソリッドを作成する。

引数

vla-object … VLAオブジェクト（Block、ModelSpace、PaperSpace）
Profile … 外形線の Region オブジェクト。
Height… オブジェクトの座標系の Z 軸に沿った押し出しの高さ。正の数値を入力すると、Z 軸の正方向にオブジェクトが押し出され、負の数値を入力すると、Z 軸の負方向にオブジェクトが押し出される。
TaperAngle … 押し出しのテーパ角度のラジアン値。テーパ角度の範囲は -90～90 度。

戻り値: 新しく作成される回転ソリッドの 3DSolid の VLA オブジェクト。

注意

2D 平面のリージョンを押し出すことしかできない。
テーパを付ける押し出しは、頂点が連続しているループによってのみ可能。
テーパ角度を大きくしたり押し出しの高さを高くすると、指定された押し出しの高さに達する前に、オブジェクトあるいはオブジェクトの一部がオブジェクトそのものと交差してしまうことがあるが、AutoCAD では、押し出した結果がソリッド本体と交差することは無い。

サンプル

(vl-load-com)
(defun c:Example_AddExtrudedSolid()
    ;; リージョンから押出ソリッド作成するサンプル。
    ;; リージョンは円弧と線分から生成。
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))
    (setq modelSpace (vla-get-ModelSpace doc))

    ;; 円弧を定義
    (setq centerPoint (vlax-3d-point 5 3 0)
          radius 2
          startAngle 0
          endAngle 3.141592)
    (setq arc (vla-AddArc modelSpace centerPoint radius startAngle endAngle))

    ;; 線分を定義
    (setq line (vla-AddLine modelSpace (vla-get-StartPoint arc) (vla-get-EndPoint arc)))
  
    (setq curves (vlax-make-safearray vlax-vbObject '(0 . 1)))
    (vlax-safearray-put-element curves 0 arc)
    (vlax-safearray-put-element curves 1 line)
        
    ;; リージョンを作成
    (setq regionObj (vla-AddRegion modelSpace curves))
    
    ;; 押し出しを定義
    (setq height 3
          taperAngle 0)
    
    ;; ソリッドを作成
    (setq solidObj (vla-AddExtrudedSolid modelSpace (vlax-safearray-get-element (vlax-variant-value regionObj) 0) height taperAngle))
    
    ;; いい感じで表示する
    (setq NewDirection (vlax-3d-point -1 -1 1))
    (setq activeViewport (vla-get-ActiveViewport doc))
    (vla-put-Direction activeViewport NewDirection)
    (vla-put-ActiveViewport doc activeViewport)
    (vla-ZoomAll acadObj)
)