「Vla-get-numberofloops」の版間の差分

2016年2月22日 (月) 21:33時点における最新版

AutoLISP Home - AutoLISP 目次 - DCL - AutoLisp関数互換表 - CAD&CGブログ - オンラインショップ- GizmoTools ヘルプセンター

構文: (vla-get-numberofloops vla-object )

機能: ハッチング境界内のループの数を取得する。

引数

vla-object … HatchのVLAオブジェクト

戻り値: ハッチング境界内のループの数。

サンプル

(vl-load-com)
(defun c:Example_NumberOfLoops()
    ;; 自動調整ハッチを作成してから境界内のループの数を
    ;; 返すサンプル。
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))
    
    ;; ハッチの定義
    (setq patternName "ANSI31"
          patternType 0
          bAssociativity :vlax-true)
    
    ;; ハッチを作成
    (setq modelSpace (vla-get-ModelSpace doc))  
    (setq hatchObj (vla-AddHatch modelSpace patternType patternName bAssociativity acHatchObject))
    
    ;; 境界のループをハッチ
    ;; An arc and a line are used to create a closed loop.
    (setq center (vlax-3d-point 5 3 0)  
          radius 3
          startAngle 0
          endAngle 3.141592)

    (setq arc (vla-AddArc modelSpace center radius startAngle endAngle))
    (setq line (vla-AddLine modelSpace (vla-get-StartPoint arc) (vla-get-EndPoint arc)))
  
    (setq outerLoop (vlax-make-safearray vlax-vbObject '(0 . 1)))
    (vlax-safearray-put-element outerLoop 0 arc)
    (vlax-safearray-put-element outerLoop 1 line)
        
    ;; ハッチング オブジェクトに外側のループを追加。
    (vla-AppendOuterLoop hatchObj outerLoop)
    
    ;; 1 つの内側のループとして最初の円を追加。
    (setq center (vlax-3d-point 5 4.5 0)
          radius 1)

    (setq circle1 (vla-AddCircle modelSpace center radius))

    (setq innerLoop1 (vlax-make-safearray vlax-vbObject '(0 . 0)))
    (vlax-safearray-put-element innerLoop1 0 circle1)
  
    (vla-AppendInnerLoop hatchObj innerLoop1)
    
    ;; 内側のループとして 2 番目の円を追加。
    (setq radius 0.5)
    (setq innerLoop2 (vlax-make-safearray vlax-vbObject '(0 . 0)))
    (setq circle2 (vla-AddCircle modelSpace center radius))
    (vlax-safearray-put-element innerLoop2 0 circle2)

    (vla-AppendInnerLoop hatchObj innerLoop2)
    (vla-ZoomAll acadObj)
    
    ;; 評価およびハッチを表示
    (vla-Evaluate hatchObj)
    (vla-Regen doc :vlax-true)
    
    ;; ハッチのループの数を検索。
    (setq numOfLoops (vla-get-NumberOfLoops hatchObj))
    (alert (strcat "ハッチ境界内のループ数は " (itoa numOfLoops)))
)

@@ 1行目: / 1行目: @@
 {{AutoLISP}}
 ; 構文
-: (vla-get-numberofloops ''vla-object'' '''' '''' )
+: (vla-get-numberofloops ''vla-object'' )