Vla-get-isopenwidth

AutoLISP Home - AutoLISP 目次 - DCL - AutoLisp関数互換表 - CAD&CGブログ - オンラインショップ- GizmoTools ヘルプセンター

構文

(vla-get-isopenwidth vla-object)

機能

ISO ハッチング パターンの ISO ペン幅を取得する。

引数

• vla-object … Hatch の VLAオブジェクト

戻り値

acISOPenWidth 列挙型

• acPenWidth000: 0.00 mm
• acPenWidth013: 0.13 mm
• acPenWidth018: 0.18 mm
• acPenWidth025: 0.25 mm
• acPenWidth035: 0.35 mm
• acPenWidth050: 0.50 mm
• acPenWidth070: 0.70 mm
• acPenWidth100: 1.00 mm
• acPenWidth140: 1.40 mm
• acPenWidth200: 2.00 mm
• acPenWidthUnk: 不明

• MEMO: 最初の 10 個の値は 1/100 ミリメートル単位のペン幅を表す。
• acPenWidthUnk の値は未知(非標準)のペン幅を示す。ハッチングを調べて acPenWidthUnk という値を受け取った場合、PatternScale プロパティを使用して非標準値を取得する。どのハッチングのペン幅を acPenWidthUnk に設定しても効果はない。
• このプロパティは、PatternScale プロパティと関係を共有する。ISO ハッチング パターンを使って作業している場合、標準の尺度値は PatternScale プロパティまたはこのプロパティを通じて入力できる。非標準のペン幅は PatternScale プロパティによってのみ入力できる。

サンプル

(vl-load-com)
(defun c:Example_ISOPenWidth()
    ;; モデル空間で連想ハッチを作成するサンプル。
    ;; ハッチパターンのISOPenWidthが返され、変更される。
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))

    ;; ハッチの定義
    (setq patternName "ANSI31"
          patternType 0
          bAssociativity :vlax-true)
    
    ;; 異尺度対応ハッチを作成
    (setq modelSpace (vla-get-ModelSpace doc))  
    (setq hatchObj (vla-AddHatch modelSpace patternType patternName bAssociativity acHatchObject))
   
    ;; ハッチのための外側の境界を作成。
    ;; 円弧と直線を閉じた境界として使用。
    (setq center (vlax-3d-point 5 3 0)
          radius 3
          startAngle 0
          endAngle 3.141592)

    (setq arc (vla-AddArc modelSpace center radius startAngle endAngle))
    (setq line (vla-AddLine modelSpace (vla-get-StartPoint arc) (vla-get-EndPoint arc)))
  
    (setq outerLoop (vlax-make-safearray vlax-vbObject '(0 . 1)))
    (vlax-safearray-put-element outerLoop 0 arc)
    (vlax-safearray-put-element outerLoop 1 line)
        
    ;; ハッチングオブジェクトに外側のループを追加
    (vla-AppendOuterLoop hatchObj outerLoop)
    
    ;; 1つ内側のループとして第1の円を追加
    (setq center (vlax-3d-point 5 4.5 0)
          radius 1)
    (setq circle1 (vla-AddCircle modelSpace center radius))

    (setq innerLoop1 (vlax-make-safearray vlax-vbObject '(0 . 0)))
    (vlax-safearray-put-element innerLoop1 0 circle1)

    (vla-AppendInnerLoop hatchObj innerLoop1)
    
    ;; 他の内側のループとして第2の円を追加
    (setq radius 0.5)
    (setq innerLoop2 (vlax-make-safearray vlax-vbObject '(0 . 0)))
    (setq circle2 (vla-AddCircle modelSpace center radius))
    (vlax-safearray-put-element innerLoop2 0 circle2)
    (vla-AppendInnerLoop hatchObj innerLoop2)
    
    ;; 評価してハッチを表示
    (vla-Evaluate hatchObj)
    (vla-Regen doc :vlax-true)
    
    ;; ハッチパターンのISOペン幅を探す
    (alert (strcat "ハッチパターンのISOペン幅は : " (itoa (vla-get-ISOPenWidth hatchObj))))

    ;; ISOペン幅を変更
    (vla-put-ISOPenWidth hatchObj acPenWidth050)
    (vla-Evaluate hatchObj)
    (vla-Regen doc :vlax-true)
    
    ;; ハッチのための新しいペン幅を表示
    (if (= (vla-get-ISOPenWidth hatchObj) acPenWidthUnk)
        ;; 非標準のペン幅
        (alert (strcat "現在のハッチパターンのISOペン幅は : " (rtos (vla-get-PatternScale hatchObj) 2)))
        ;; 標準のペン幅
        (alert (strcat "現在のハッチパターンのISOペン幅は : " (itoa (vla-get-ISOPenWidth hatchObj))))
    )
)

---

関連事項

• vlax-get-acad-object
• vla-get-activedocument
• vla-put-isopenwidth
• vla-get-isopenwidth
• vla-evaluate