Vla-put-textprefixのソースを表示

{{AutoLISP}}
; 構文
: (vla-put-textprefix ''vla-object'' ''prefix'' )


; 機能
: 寸法値の接頭表記を指定する。 


; 引数
:* vla-object … VLAオブジェクト（Dim3PointAngular、DimAligned、DimAngular、DimArcLength、DimDiametric、Dimension、DimOrdinate、DimRadial、DimRadialLarge、DimRotated）
:* prefix …  寸法値の接頭表記。


; 戻り値
: nil


* MEMO：このプロパティの初期値は ""（空文字）。
* 注: このプロパティは、指定された寸法でシステム変数 DIMPOST[接頭/接尾表記]の値を変更する。


; サンプル
<pre class="brush:autolisp;">
(vl-load-com)
(defun c:Example_TextPrefix()
    ;; 寸法を作成して寸法値の接頭表記を変更するサンプル
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))
    
    ;; 寸法の定義
    (setq point1 (vlax-3d-point 0 5 0)
          point2 (vlax-3d-point 5 5 0)
          location (vlax-3d-point 5 7 0))
    
    ;; 寸法を作成
    (setq modelSpace (vla-get-ModelSpace doc))
    (setq dimObj (vla-AddDimAligned modelSpace point1 point2 location))
    
    (vla-ZoomAll acadObj)

    ;; 接頭表記を指定
    (setq prefix (vla-GetString (vla-get-Utility doc) :vlax-false "\n接頭表記を入力して Enter : "))
    (vla-put-TextPrefix dimObj prefix)   ;; 結果をコミットする

    (vla-Regen doc acAllViewports)
    
    ;; 取得
    (setq prefix (vla-get-TextPrefix dimObj))
    (if (/= prefix "")
        (alert (strcat "次の新しい接頭表記に変更しました : " prefix))
        (alert "変更無理でした")
    )
)
</pre>

-----
関連事項
* [[vlax-get-acad-object]]
* [[vla-get-activedocument]]
* [[vla-put-textprefix]]
* [[vla-get-textprefix]]


[[Category:AutoLISP]]