Vla-getloopat

提供:GizmoLabs - だいたい CAD LISP なサイト
2016年2月13日 (土) 19:21時点におけるGizmon (トーク | 投稿記録)による版
(差分) ← 古い版 | 最新版 (差分) | 新しい版 → (差分)
構文
(vla-getloopat vla-object Index Loop )


機能
指定されたインデックスで、ハッチング ループを取得する。


引数
  • vla-object … Hatch のVLAオブジェクト
  • Index … 0 を含む正の整数。
  • Loop … ループを形成するオブジェクトまたはオブジェクトの配列。


戻り値
nil


サンプル
(vl-load-com)
(defun c:Example_GetLoopAt()
    ;; ハッチを作成して境界を設定するサンプル
    (setq acadObj (vlax-get-acad-object))
    (setq doc (vla-get-ActiveDocument acadObj))
    (setq modelSpace (vla-get-ModelSpace doc))
    
    ;; ハッチの定義
    (setq patternName "ANSI31"
          patternType acHatchPatternTypePreDefined
          bAssociativity :vlax-true)
    
    ;; ハッチを作成
    (setq modelSpace (vla-get-ModelSpace doc))  
    (setq hatchObj (vla-AddHatch modelSpace patternType patternName bAssociativity acHatchObject))
    
    ;; ハッチの境界を作成
    ;; An arc and a line are used to create a closed loop.
    (setq center (vlax-3d-point 5 3 0)
          radius 3
          startAngle 0
          endAngle 3.141592)
  
    (setq arcObj (vla-AddArc modelSpace center radius startAngle endAngle))
    (setq lineObj (vla-AddLine modelSpace (vla-get-StartPoint arcObj) (vla-get-EndPoint arcObj)))

    (setq outerLoop (vlax-make-safearray vlax-vbObject '(0 . 1)))
    (vlax-safearray-put-element outerLoop 0 arcObj)
    (vlax-safearray-put-element outerLoop 1 lineObj)

    ;; ハッチの境界を確定
    (vla-AppendOuterLoop hatchObj outerLoop)
    
    ;; ハッチの境界を定義
    (setq center (vlax-3d-point 5 4.5 0)
          radius 1)

    (setq innerLoop1 (vlax-make-safearray vlax-vbObject '(0 . 0)))
    (vlax-safearray-put-element innerLoop1 0 (vla-AddCircle modelSpace center radius))
    (vla-AppendInnerLoop hatchObj innerLoop1)
    
    ;; 2つめのハッチ境界を追加
    (setq radius 0.5)
    (setq innerLoop2 (vlax-make-safearray vlax-vbObject '(0 . 0)))
    (vlax-safearray-put-element innerLoop2 0 (vla-AddCircle modelSpace center radius))
    (vla-AppendInnerLoop hatchObj innerLoop2)
    
    ;; 確定
    (vla-Evaluate hatchObj)
    (vla-Regen doc :vlax-true)
    
    ;; 境界を取得
    (vla-GetLoopAt hatchObj 0 'loopObjs) 
    
    ;; 境界の図形を取得
    (setq I 0
          objName "")
    (while (>= (vlax-safearray-get-u-bound loopObjs 1) I)
        (setq objName (strcat objName (vla-get-ObjectName (vlax-safearray-get-element loopObjs I)) ", "))
        (setq I (1+ I))
    )
    
    (alert (strcat "最初のハッチング境界は : " objName))
)

関連事項